Le Forum des Utilisateurs Sage

Bonjour,

J'aimerai qu'une ame charitable m'aide pour avoir le solde d'un compte dans excel.
Je peux ramener pas mal d'info avec msquery, mais je n'arrive pas à avoir le solde d'un compte si ce n'est en "bidouillant" de façon non satisfaisante.

Sage compta ligne 100 / V14 + drivers ODBC.

Merci d'avance

Bonjour,
je travaille sous Sage 100 gest co et compta version 10 base propriétaire.
Ci dessous le code qui me permet d'importer une balance générale sous excel avec les totaux debit crédit et les soldes.

Cela répondra peut être à votre question.

il faut d'abord:
-créer un dsn à partir du pilote sage gestion commerciale (ici "BASEGESTCO")
-référencer l'activeX microsoft ADO version ..., dans le fichier excel,
-Déclarer les fonctions TotalMvtSolde, ....
comme suit

Code: Tout sélectionner

Option Explicit
Declare Function TotalMvtSolde Lib "CBODBC32" (ByVal CG_Num As String, ByVal CT_Num As String, ByVal JO_Num As String, ByVal Debut As String, ByVal Fin As String, cumul As Double) As Integer
Declare Function TotalMvtDebit Lib "CBODBC32" (ByVal CG_Num As String, ByVal CT_Num As String, ByVal JO_Num As String, ByVal Debut As String, ByVal Fin As String, cumul As Double) As Integer
Declare Function TotalMvtCredit Lib "CBODBC32" (ByVal CG_Num As String, ByVal CT_Num As String, ByVal JO_Num As String, ByVal Debut As String, ByVal Fin As String, cumul As Double) As Integer


et ensuite travailler sur une liaison ADODB pour extraire les données recherchées,

Code: Tout sélectionner

Sub ImporterBalance(Debut As String, Fin As String)
Dim BASE As New ADODB.Connection
Dim RST_CG As New ADODB.Recordset
Dim RSQL As String
Dim i As Long
Dim Code As Integer
Dim TotalDebit As Double, TotalCredit As Double, solde As Double

BASE.Open "Dsn=BASEGESTCO;Uid=xxx"
RSQL = "SELECT * FROM F_COMPTEG"
RST_CG.Open RSQL, BASE, adOpenForwardOnly, adLockOptimistic
If RST_CG.BOF And RST_CG.EOF Then GoTo Fin
i = 0

Do Until RST_CG.EOF
    Code = TotalMvtDebit(RST_CG("CG_NUM"), "", "", Debut, Fin, TotalDebit)
    Code = TotalMvtCredit(RST_CG("CG_NUM"), "", "", Debut, Fin, TotalCredit)
    If Not (TotalDebit = 0 And TotalCredit = 0) Then
        ActiveCell.Offset(1, 0).Select
        ActiveCell.Offset(0, 0) = RST_CG("CG_NUM")
        ActiveCell.Offset(0, 1) = RST_CG("CG_INTITULE")
        ActiveCell.Offset(0, 2) = TotalDebit
        ActiveCell.Offset(0, 3) = TotalCredit
        Code = TotalMvtSolde(RST_CG("CG_NUM"), "", "", Debut, Fin, solde)
        If solde > 0 Then
            ActiveCell.Offset(0, 4) = solde
        Else
            ActiveCell.Offset(0, 5) = -solde
        End If
        i = i + 1
    End If
    RST_CG.MoveNext
Loop

Fin:
RST_CG.Close
BASE.Close
End Sub


A+

Bonsoir,

Merci beaucoup pour cette routine.

Initialement ce n'était pas ce que je recherchais, mais effectivement, je devrais arriver au même résultat.

Je teste.

Encore Merci

Bonjour,
J'essaye de reproduire ce code sous Excel 2007 (je ne suis pas un spécialiste du vba sous Excel).
Impossilble de le faire fonctionner. En fait je ne peux pas mémoriser la macro sur un bouton et qd je l'exècute, j'obtiens "argument non facultatif"

Bien sûr ma DSN existe sous le même nom (pointe sur bijou - odbc Sage 16.02).

Est-ce que quelqu'un aurait la gentillesse de me fournir le même exemple dans un fichier Excel. Je me demande si, par mauvaise connaissance du vba sous Excel, si je n'oublie pas qq chose ??

Merci si qq peut m'aider
Thibault

Bonjour,

voilà la marche à suivre pour tester le code.

Ouvrir un classeur excel 2007, puis l'éditeur visual basic à partir du menu Developpeur.
Inserer un module et y coller le code suivant :

Code: Tout sélectionner

'***************************************************************************************************************************************
Option Explicit
Declare Function TotalMvtSolde Lib "CBODBC32" (ByVal CG_Num As String, ByVal CT_Num As String, ByVal JO_Num As String, ByVal Debut As String, ByVal Fin As String, cumul As Double) As Integer
Declare Function TotalMvtDebit Lib "CBODBC32" (ByVal CG_Num As String, ByVal CT_Num As String, ByVal JO_Num As String, ByVal Debut As String, ByVal Fin As String, cumul As Double) As Integer
Declare Function TotalMvtCredit Lib "CBODBC32" (ByVal CG_Num As String, ByVal CT_Num As String, ByVal JO_Num As String, ByVal Debut As String, ByVal Fin As String, cumul As Double) As Integer

Sub ImporterBalance(Debut As String, Fin As String)
Dim BASE As New ADODB.Connection
Dim RST_CG As New ADODB.Recordset
Dim RSQL As String
Dim i As Long
Dim Code As Integer
Dim TotalDebit As Double, TotalCredit As Double, solde As Double

BASE.Open "Dsn=BIJOUGC;Uid="
RSQL = "SELECT * FROM F_COMPTEG"
RST_CG.Open RSQL, BASE, adOpenForwardOnly, adLockOptimistic
If RST_CG.BOF And RST_CG.EOF Then GoTo Fin
i = 0

Do Until RST_CG.EOF
Code = TotalMvtDebit(RST_CG("CG_NUM"), "", "", Debut, Fin, TotalDebit)
Code = TotalMvtCredit(RST_CG("CG_NUM"), "", "", Debut, Fin, TotalCredit)
If Not (TotalDebit = 0 And TotalCredit = 0) Then
ActiveCell.Offset(1, 0).Select
ActiveCell.Offset(0, 0) = RST_CG("CG_NUM")
ActiveCell.Offset(0, 1) = RST_CG("CG_INTITULE")
ActiveCell.Offset(0, 2) = TotalDebit
ActiveCell.Offset(0, 3) = TotalCredit
Code = TotalMvtSolde(RST_CG("CG_NUM"), "", "", Debut, Fin, solde)
If solde > 0 Then
ActiveCell.Offset(0, 4) = solde
Else
ActiveCell.Offset(0, 5) = -solde
End If
i = i + 1
End If
RST_CG.MoveNext
Loop

Fin:
RST_CG.Close
BASE.Close
End Sub

Sub test()
ImporterBalance "010409", "310310"
End Sub
'**************************************************************************************************************************************


S'assurer que la ligne BASE.Open "Dsn=BIJOUGC;Uid=" pointe bien sur une dsn definie.

Placer ensuite le curseur a l'interieur de la procedure sub Test() et appuyer sur F5.
La balance générale 4 colonnes se copie dans la feuille active du classeur.

J'ai testé ce code avec Excel 2007 et Sage Ligne100 V16.05 base propriétaire et ça Marche!!!

Bon Courage

Michel

Merci Michel
ça marche nickel